2025 March Madness Bracket Picker

Overview

As promised, here is the bracket picker tool for 2025:

It is purely of interest to Excel geeks as a showcase. Anyone submitting a bracket is doing so online. It's not really my thing, but it's a fascinating case study for both design and logic. The above image is the dumbest bracket ever, highest seed wins every game. Notice that it now has the regional finals titled, within the single array formula. Pick quick, games start soon! Have fun and good luck.

If you missed my earlier post, please check it out for complete explanation. In this new download, the Info sheet has more information and a basic update procedure. For the true geeks, the bracket array formula is updated below. ibracket and blankrows functions are given in the linked post.

Bracket Array

/**bracket assembly*/
bracket = LET(
    header, {
        "1st round",
        "2nd round",
        "sweet sixteen",
        "elite eight",
        "final four",
        "championship",
        "final four",
        "elite eight",
        "sweet sixteen",
        "2nd round",
        "1st round"
    },
    r1g1, FILTER(Games[id] & " " & Games[team], Games[n] < 33),
    r1g2, FILTER(Games[team] & " " & Games[id], Games[n] > 32),
    regns, {"S","South";"W","West";"E","East";"M","Midwest"},
    regn1, XLOOKUP(LEFT(XLOOKUP(9,Games[n],Games[id],""),1),INDEX(regns,,1),INDEX(regns,,2),"")&" Final",
    regn2, XLOOKUP(LEFT(XLOOKUP(25,Games[n],Games[id],""),1),INDEX(regns,,1),INDEX(regns,,2),"")&" Final",
    regn3, XLOOKUP(LEFT(XLOOKUP(41,Games[n],Games[id],""),1),INDEX(regns,,1),INDEX(regns,,2),"")&" Final",
    regn4, XLOOKUP(LEFT(XLOOKUP(57,Games[n],Games[id],""),1),INDEX(regns,,1),INDEX(regns,,2),"")&" Final",
    r2g18, IF(
        tround <2,
        blankrows(32),
        VSTACK(
            blankrows(1),
            ibracket(2, 1, 2),
            ibracket(2, 2, 2),
            ibracket(2, 3, 2),
            ibracket(2, 4, 2),
            ibracket(2, 5, 2),
            ibracket(2, 6, 2),
            ibracket(2, 7, 2),
            ibracket(2, 8, 1)
        )
    ),
    r2g9F, IF(
        tround <2,
        blankrows(32),
        VSTACK(
            blankrows(1),
            ibracket(2, 9, 2),
            ibracket(2, 10, 2),
            ibracket(2, 11, 2),
            ibracket(2, 12, 2),
            ibracket(2, 13, 2),
            ibracket(2, 14, 2),
            ibracket(2, 15, 2),
            ibracket(2, 16, 1)
        )
    ),
    r3g14, IF(
        tround <3,
        blankrows(32),
        VSTACK(blankrows(3), ibracket(3, 1, 6), ibracket(3, 2, 6), ibracket(3, 3, 6), ibracket(3, 4, 3))
    ),
    r3g58, IF(
        tround <3,
        blankrows(32),
        VSTACK(blankrows(3), ibracket(3, 5, 6), ibracket(3, 6, 6), ibracket(3, 7, 6), ibracket(3, 8, 3))
    ),
    r4g12, IF(tround <4, blankrows(32), VSTACK(blankrows(6), IF(tround>3,regn1,blankrows(1)), ibracket(4, 1, 13), IF(tround>3,regn2,blankrows(1)), ibracket(4, 2, 7))),
    r4g34, IF(tround <4, blankrows(32), VSTACK(blankrows(6), IF(tround>3,regn3,blankrows(1)), ibracket(4, 3, 13), IF(tround>3,regn4,blankrows(1)), ibracket(4, 4, 7))),
    r5g1, IF(tround <5, blankrows(32), VSTACK(blankrows(15), ibracket(5, 1, 15))),
    r5g2, IF(tround <5, blankrows(32), VSTACK(blankrows(15), ibracket(5, 2, 15))),
    r6nf, IF(tround <6, blankrows(32), VSTACK(IF(tround=6,blankrows(12),VSTACK(blankrows(10),ibracket(7, 1, 1))), ibracket(6, 1, 18))),
    IFERROR(
        VSTACK(header, HSTACK(r1g1, r2g18, r3g14, r4g12, r5g1, r6nf, r5g2, r4g34, r3g58, r2g9F, r1g2)),
        ""
    )
);