March Madness Bracket Picker

Overview

It's almost time for the 2025 March Madness Basketball Tournament! Many who are fans will fill out a bracket online to be ranked among the millions of other fans, and some are curious what xlegant has to do with it. Others have no interest in MM at all and are here for curiosity alone. My aim is to appeal to all with a simple and fun solution that showcases elegant Excel techniques. Click here to download the 2024 bracket file, for learning and practice. When the 2025 bracket is announced I will post an updated file.

2025 Schedule

The bracket is announced on Selection Sunday, March 16, 2025, at 6:00 PM ET
Brackets should be picked before play begins with the First Four on March 18-19

Tournament Structure

The main tournament is six rounds, beginning in round one with 64 teams, sixteen in each of four regions, ending in round six with the national champion. Four of the 64 teams are the winners of an initial "first four" round of eight teams, which I call "round 0".

Bracket Selection

There are many ways to approach bracket picks. The seeding is a good start. For example, in round 1, the 1 seed plays the 16 seed and will almost always win; it's less certain when the 8 and 9 seeds play each other. The trick is to predict the upsets. Fans who follow the season and know the team matchups can make educated guesses. But there is always an element of chance.

Smart people have spent years trying to create a winning bracket system. There are certainly some things an amateur can do in Excel for the intellectual challenge of it, perhaps I will entertain some ideas in a later post. For now, the gut method will suffice as we focus on the process of recording selections. For interest, here's some background on the science:

The absurd odds of a perfect NCAA bracket | NCAA.com

Input Table

It is good practice to store input data in a static table for reference. The data may be downloaded or swiped from the source and formatted as a table with no formulas. The tournament is announced in mid-March as a list of 68 teams with region, conference, record, regional seed, overall seed, and selection type. In my table I've added a record number [n] and an [id] which combines region and seed. This table structure can be used year after year and updated with the team data.

This table, Teams2024, has 72 rows, for the 68 teams plus four placeholder "tbd" rows. The reason for this will be seen in the selection table.

Selection Table

Selections for the first four, which I call "round 0," are in a separate table, Round0, from the main 64-team, six-round table, Games. The round to be picked is always highlighted in yellow, with games in alternating colors. While in round 0, the Games placeholder rows are yellow pending round 0 selections. Column and rows groups are used to easily hide and show sections as needed.

Games columns [n] and [id] are static. Column [team] could be copied but is calculated with the formula below to respond to the round 0 picks, to finalize the 64 bracket teams without clumsy copying.

The three remaining columns are calculated to aid the process.

[wins] =COUNTIF(Games[@[r1]:[r6]],"w")
counts wins, formatted with data bars, and feeds the next column
[w] =IFERROR(IF([@wins]=MAX([wins]),"→",""),"")
flags the winners of a completed round, aids filtering
[g] =IFERROR(ROUNDUP([@n]/POWER(2,tround),0),"")
calculates group for flagging game opponents

tround (tournament round, to distinguish from ROUND function) returns the lowest incomplete round.

tround = IFS(
    COUNTIF(Round0[r0], "w") < 4,0,
    COUNTIF(Games[r1], "w") < 32,1,
    COUNTIF(Games[r2], "w") < 16,2,
    COUNTIF(Games[r3], "w") < 8,3,
    COUNTIF(Games[r4], "w") < 4,4,
    COUNTIF(Games[r5], "w") < 2,5,
    COUNTIF(Games[r6], "w") < 1,6,
    TRUE,7
);

Selection Process

Picks are made by entering "w" (either upper or lower case) for win in the yellow column for one of the two teams in each game.

Once all winners have been picked for the round, the highlight shifts to the next round, and the groups expand by double. In round 2, each group is four teams: the two round 1 winners play in round 2, and the other two go home. In this condition, before starting round 2 picks, column [w] can be used to filter out the losers, collapsing the groups back to two rows representing each game.

With [w] filtered, the matchups are seen.

Filtering matches the table rows to the round name (sweet sixteen, elite eight, final four).

2024 Results Table

The 2024 tournament results are included in a static table in a column group. For practice, wins can be typed in or copied by round or all at once. To copy a column, select the data column as shown, by hovering above the column header until the down arrow appears. To paste, select the top yellow cell and use Ctrl+Shift+V to paste values only. This also works when the selection table is filtered as described above, and when multiple columns are selected.

Conditional Formatting

Conditional Formatting rules are applicable to the tables and the bracket but must be written with range references.

Clear the fill from non-blank bracket cells
Highlight round 0
Highlight rounds 1-6
Highlight unpicked round 0 teams
Data bar of win count
Change fill color of odd group numbers

Bracket

The bracket is in another column group for easy show/hide. It is built from the selection table via a single array formula. Rounds 2-6 remain blank until complete. With the other column and row groups collapsed, it can be printed on a single page.

Bracket Array

Function ibracket is an internal function used in the bracket formula. It takes round, group and optional [blanks] inputs and returns a two-row array of the next game opponents, padded with the optional blanks. Note that the FILTER in gnext uses two criteria multiplied to select the group number AND the "W" from the previous round.

ibracket = LAMBDA(round, group, [blanks],
    LET(
        rcol, CHOOSE(
            MIN(MAX(round, 2), 7),
            NA(),
            Games[r1],
            Games[r2],
            Games[r3],
            Games[r4],
            Games[r5],
            Games[r6]
        ),

        gnext, FILTER(Games[team], (ROUNDUP(Games[n] / POWER(2, round), 0) = group) * (rcol = "W")),
        IFERROR(VSTACK(gnext, blankrows(blanks)), "")
    )
);

Function blankrows simply creates a blank array of n rows.

blankrows = LAMBDA(rows,
    CHOOSE(
        MIN(MAX(rows, 1), 20),
        /*01*/"",
        /*02*/{""; ""},
        /*03*/{""; ""; ""},
        /*04*/{""; ""; ""; ""},
        /*05*/{""; ""; ""; ""; ""},
(etc.)

bracket builds the graphic, beginning with the 64 teams in round 1, then padding blank rows to space each game in rounds 2-6.

bracket = LET(
    header, {
        "1st round",
        "2nd round",
        "sweet sixteen",
        "elite eight",
        "final four",
        "championship",
        "final four",
        "elite eight",
        "sweet sixteen",
        "2nd round",
        "1st round"
    },
    r1g1, FILTER(Games[id] & " " & Games[team], Games[n] < 33),
    r1g2, FILTER(Games[team] & " " & Games[id], Games[n] > 32),
    r2g18, IF(
        tround = 1,
        blankrows(32),
        VSTACK(
            blankrows(1),
            ibracket(2, 1, 2),
            ibracket(2, 2, 2),
            ibracket(2, 3, 2),
            ibracket(2, 4, 2),
            ibracket(2, 5, 2),
            ibracket(2, 6, 2),
            ibracket(2, 7, 2),
            ibracket(2, 8, 1)
        )
    ),
    r2g9F, IF(
        tround = 1,
        blankrows(32),
        VSTACK(
            blankrows(1),
            ibracket(2, 9, 2),
            ibracket(2, 10, 2),
            ibracket(2, 11, 2),
            ibracket(2, 12, 2),
            ibracket(2, 13, 2),
            ibracket(2, 14, 2),
            ibracket(2, 15, 2),
            ibracket(2, 16, 1)
        )
    ),
    r3g14, IF(
        tround = 2,
        blankrows(32),
        VSTACK(blankrows(3), ibracket(3, 1, 6), ibracket(3, 2, 6), ibracket(3, 3, 6), ibracket(3, 4, 3))
    ),
    r3g58, IF(
        tround = 2,
        blankrows(32),
        VSTACK(blankrows(3), ibracket(3, 5, 6), ibracket(3, 6, 6), ibracket(3, 7, 6), ibracket(3, 8, 3))
    ),
    r4g12, IF(tround = 3, blankrows(32), VSTACK(blankrows(7), ibracket(4, 1, 14), ibracket(4, 2, 7))),
    r4g34, IF(tround = 3, blankrows(32), VSTACK(blankrows(7), ibracket(4, 3, 14), ibracket(4, 4, 7))),
    r5g1, IF(tround = 4, blankrows(32), VSTACK(blankrows(15), ibracket(5, 1, 15))),
    r5g2, IF(tround = 4, blankrows(32), VSTACK(blankrows(15), ibracket(5, 2, 15))),
    r6nc, IF(tround = 5, blankrows(32), VSTACK(blankrows(10), ibracket(7, 1, 1), ibracket(6, 1, 18))),
    IFERROR(
        VSTACK(header, HSTACK(r1g1, r2g18, r3g14, r4g12, r5g1, r6nc, r5g2, r4g34, r3g58, r2g9F, r1g2)),
        ""
    )
);